openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package dwarfs

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=dwarfs
pkgver=0.9.9
pkgrel=1
pkgdesc="A fast high compression read-only file system"
url="https://github.com/mhx/dwarfs"
arch=(x86_64)
license=(GPL-3.0-only)
depends=(boost-libs brotli double-conversion flac fmt fuse3 google-glog jemalloc libarchive libunwind xxhash)
makedepends=(boost chrono-date cmake libdwarf libevent ninja python-mistletoe range-v3 ruby-ronn-ng utf8cpp)
source=(${url}/releases/download/v${pkgver}/dwarfs-${pkgver}.tar.xz)
sha256sums=('f4638e589d5ae7038ca9461470a938d7bb755b1eae6533502a4f87f97c59c7f4')

build() {
	local _cflags="-DNDEBUG -Wno-uninitialized"
	export CFLAGS="${CFLAGS} ${_cflags}"
	export CXXFLAGS="${CXXFLAGS} ${_cflags}"

cmake -S ${pkgname}-${pkgver} \
		-B build \
		-G Ninja \
		-W no-dev \
		-D CMAKE_INSTALL_PREFIX=/usr \
		-D CMAKE_BUILD_TYPE=None \
		-D PREFER_SYSTEM_ZSTD=ON \
		-D PREFER_SYSTEM_XXHASH=ON \
		-D PREFER_SYSTEM_LIBFMT=ON

cmake --build build
}

package() {
	cmake --install build --prefix "${pkgdir}"/usr

mv "${pkgdir}"/usr/sbin/* "${pkgdir}"/usr/bin
	rmdir "${pkgdir}"/usr/sbin
}

Places

File PKGBUILD of Package dwarfs

Places