openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package zig-git

pkgname=zig-git
_srcname=zig
pkgver=0.13.0
pkgrel=3
pkgdesc='a general-purpose programming language and toolchain for maintaining robust, optimal, and reusable software'
arch=('x86_64')
url='https://ziglang.org/'
license=('MIT')
makedepends=('cmake' 'ninja' 'clang' 'python' 'git')
provides=('zig')
conflicts=('zig')
source=("$_srcname.tar"
        "llvm-project.tar")
b2sums=('SKIP'
        'SKIP')

prepare() {
    cd "$_srcname"
    sed -i '/llvm_has_xtensa/s/false/true/' stage1/config.zig.in
}

build() {
    ulimit -n 4096

local cmake_llvm_vars=(
        CMAKE_INSTALL_PREFIX=$srcdir/LLVM_OUT
        CMAKE_PREFIX_PATH=$srcdir/LLVM_OUT
        CMAKE_BUILD_TYPE=Release
        LLVM_ENABLE_PROJECTS="lld;clang"
        LLVM_ENABLE_LIBXML2=OFF
        LLVM_ENABLE_TERMINFO=OFF
        LLVM_ENABLE_LIBEDIT=OFF
        LLVM_ENABLE_ASSERTIONS=ON
        LLVM_ENABLE_BINDINGS=OFF
        LLVM_PARALLEL_LINK_JOBS=1

CMAKE_C_COMPILER="clang;-march=znver3;-mtune=znver3;-O3"
        CMAKE_CXX_COMPILER="clang++;-march=znver3;-mtune=znver3;-O3"
        LLVM_CCACHE_BUILD=ON
        LLVM_USE_LINKER=mold
        LLVM_ENABLE_LTO=Thin
        LLVM_BINUTILS_INCDIR=/usr/include

LLVM_EXPERIMENTAL_TARGETS_TO_BUILD=Xtensa

LLVM_INCLUDE_BENCHMARKS=OFF
        LLVM_INCLUDE_EXAMPLES=OFF
        LLVM_INCLUDE_TESTS=OFF
        LLVM_INCLUDE_DOCS=OFF
    )
    cmake -B llvmbuild -G Ninja "${cmake_llvm_vars[@]/#/-D}" llvm-project/llvm
    cmake --build llvmbuild
    cmake --install llvmbuild

export PATH=$srcdir/LLVM_OUT:$PATH
    local cmake_vars=(
        CMAKE_INSTALL_PREFIX=/usr
        CMAKE_BUILD_TYPE=None

ZIG_STATIC_LLVM=ON
        CMAKE_PREFIX_PATH=$srcdir/LLVM_OUT

ZIG_TARGET_MCPU=znver3

CMAKE_C_COMPILER="clang;-march=znver3;-mtune=znver3;-O3"
        CMAKE_CXX_COMPILER="clang++;-march=znver3;-mtune=znver3;-O3"
        ZIG_USE_CCACHE=ON
    )
    cmake -B build -G Ninja "${cmake_vars[@]/#/-D}" "$_srcname"
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}

Places

File PKGBUILD of Package zig-git

Places